AutoHotKey files in my Startup

I have the following AutoHotKey files load when system boots:

Common Scripts.ahk

#n::Run C:\Documents and Settings\I034708\My Documents\My Dropbox\Sridhar\Programs\notepad2\Notepad2.exe

#o::Run Outlook

#i::Run iexplore

#f::Run firefox

#x:: Run excel

#w:: Run winword

#p:: Run powerpnt

^!C::
	Run, C:\Users\i034708\Documents\My Dropbox\Sridhar\Programs\trout_portable\trout.exe /clipboard
	Sleep, 2000
	FileCopy, % clipboard, C:\Users\i034708\Documents\My Dropbox\Sridhar\Music - Good Songs
return

What the above script does is allow me to launch common programs using keyboard shortcuts like so:

KatMouse.ahk

CoordMode, Mouse, Screen
return

WheelUp::
   MouseGetPos, m_x, m_y
   hw_m_target := DllCall( "WindowFromPoint", "int", m_x, "int", m_y )

   ; WM_MOUSEWHEEL
   ;   WHEEL_DELTA = 120
   SendMessage, 0x20A, 120 << 16, ( m_y << 16 )|m_x,, ahk_id %hw_m_target%
return

WheelDown::
   MouseGetPos, m_x, m_y
   hw_m_target := DllCall( "WindowFromPoint", "int", m_x, "int", m_y )

   ; WM_MOUSEWHEEL
   ;   WHEEL_DELTA = 120
   SendMessage, 0x20A, -120 << 16, ( m_y << 16 )|m_x,, ahk_id %hw_m_target%
return

With the above script running, I can scroll using the mouse wheel in scrollable regions without having to click the mouse in the scrollable region. This is similar to the (part of) functionality offered by a freeware called KatMouse.

OnTop.ahk

; Always on Top toggle for active window - by wr975 / DonationCoder.com
; Source: http://www.donationcoder.com/Forums/bb/index.php?topic=6374.msg44781#msg44781
; --------------------------------------
#a::
WinGet, ExStyle, ExStyle, A
if (ExStyle & 0x8)
{
	WinSet,AlwaysOnTop,off,A
        TrayTip, AlwaysOnTop, Disabled
}
else
{
	WinSet,AlwaysOnTop,on,A
        TrayTip, AlwaysOnTop, Enabled
}
sleep 2000
TrayTip
return

I frequently show rhymes (downloaded from YouTube) to my daughter in VLC media player at double the video size while working on my own stuff. The above script makes any window stay on top by pressing Win + A. To make the window behave normally again, the same hotkey is to be pressed.

RemapKeys.ahk

Insert::PrintScreen

The laptop I work on has the same physical key for insert and prnt scrn. I rarely ever use the insert option and to take screenshots I use prnt scrn a lot. But since both are on the same key, I will need to press Fn key for prnt scrn to work. The above script maps the insert key to prnt scrn thereby helping me from having to hold the Fn key down.

Related Posts

• 20 August, 2010 -- Keyconfig in Firefox (7)